dotfiles/.config/nixpkgs/neovim/neovim.nix

{ lib
, stdenv
, writeTextFile
, neovim
, neovim-unwrapped
, fd
, ripgrep
, nodePackages
, vimPlugins
, vimUtils
, fetchFromGitHub
, withPlayground ? false
}:
let
  buildNeovimPlugin = attrs: stdenv.mkDerivation ({
    forceShare= [ "man" "info" ];

    installPhase = ''
      cp -r . $out

      if [ -d "$out/doc" ]; then
        ${neovim-unwrapped}/bin/nvim -N -u NONE -i NONE -n -E -s -V1 -c "helptags $out/doc" +quit!
      fi
    '';
  } // attrs);
  plugins = import ./plugins.nix { inherit buildNeovimPlugin fetchFromGitHub; };
  extra-treesitter-textobjects = writeTextFile {
    name = "extra-treesitter-textobjects";
    destination = "/after/queries/javascript/textobjects.scm";
    text = ''
      ; support swapping elements inside arrays too
      (array "," . (_) @parameter.inner)
      (array . (_) @parameter.inner ",")
    '';
  };
  extra-tsc-compiler = writeTextFile {
    name = "extra-tsc-compiler";
    destination = "/after/compiler/tsc.vim";
    text = ''
      CompilerSet makeprg=node_modules/.bin/tsc\ --incremental\ --noEmit
    '';
  };
  extraPath = [
    fd
    ripgrep
    nodePackages.typescript-language-server
    nodePackages.eslint_d
  ];
in
neovim.override {
  extraMakeWrapperArgs = "--prefix PATH : ${lib.makeBinPath extraPath}";
  configure = {
    customRC = ''
      source ${./settings.lua}
      source ${./plugins.lua}
      source ${./mappings.lua}
      source ${./autocmd.lua}
      source ${./lsp.lua}
      source ${./theme.lua}
    '' + lib.optionalString withPlayground ''
      source ${./playground.lua}
    '';
    packages.myVimPackage = with vimPlugins; {
      start = plugins ++ [
        (nvim-treesitter.withPlugins (p: with p; [
          tree-sitter-bash
          tree-sitter-css
          tree-sitter-go
          tree-sitter-javascript
          tree-sitter-json
          tree-sitter-lua
          tree-sitter-nix
          tree-sitter-ruby
          tree-sitter-tsx
          tree-sitter-typescript
        ] ++ lib.optionals withPlayground [
          tree-sitter-query
        ]))
        extra-treesitter-textobjects
        extra-tsc-compiler
      ] ++ lib.optionals withPlayground [
        playground
      ];
    };
  };
}