dotfiles/.config/nixpkgs/neovim/flake.nix

{
  description = "Neovim configuration";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, flake-utils }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [(final: prev: {
            treesitter = prev.treesitter.override {
              extraGrammars = [
                (final.fetchFromGitHub {
                  owner = "ckafi";
                  repo = "tree-sitter-elvish";
                  rev = "f32711e31e987fd5c2c002f3daba02f25c68672f";
                  hash = "sha256-/3npcIfTH8w5ekLTb//ZCTxuSGhOXkUBaCq3WWcK2J4=";
                })
              ];
            };

            node-lsp = final.callPackage ./node-lsp {};
          })];
        };
      in
      {
        packages.neovim = pkgs.callPackage ./neovim.nix {};
        packages.neovim-with-playground = pkgs.callPackage ./neovim.nix { withPlayground = true; };
        packages.neovim-with-luadev = pkgs.callPackage ./neovim.nix { withLuadev = true; };
        packages.default = self.packages.${system}.neovim;
      }
    );
}