dotfiles/.config/nixpkgs/overlays/userPackages.nix

self: super:

let
  nixpkgs-unstable = import <unstable> {};
in
{
  userPackages = super.userPackages or {

    inherit (self)
      # cli
      vimHugeX
      neovim
      neovim-remote
      git
      git-lfs
      feh
      ripgrep
      jq
      yq
      tree
      fzf
      dnsutils
      httpie
      htop
      bc
      pv
      caddy
      openssl
      pwgen
      gnupg
      whois
      traceroute
      gnumake
      tig
      gettext
      unzip
      zip
      shellcheck
      any-nix-shell

      # apps
      pcmanfm
      lxappearance
      pavucontrol
      pamixer
      gnumeric
      mpv

      # work
      insomnia
      awscli
      docker
      docker_compose
      amazon-ecr-credential-helper
      virtmanager
      tmux-cssh
      ;


    xrdb = self.xorg.xrdb;
    qterminal = self.lxqt.qterminal;
    mps-youtube = self.python36Packages.mps-youtube;
    keepassxc = nixpkgs-unstable.keepassxc.override { qtbase = self.qt5.qtbase; };
    op = nixpkgs-unstable._1password;
    deadbeef = nixpkgs-unstable.deadbeef;
    cfn-lint = nixpkgs-unstable.python27.pkgs.callPackage ./packages/cfn-lint.nix {};
    cfn_flip = nixpkgs-unstable.python27.pkgs.callPackage ./packages/cfn_flip.nix {};
    wl-clipboard = nixpkgs-unstable.callPackage ./packages/wl-clipboard.nix {};

    nix-rebuild = super.writeScriptBin "nix-rebuild" ''
      #!${super.stdenv.shell}
      if ! command -v nix-env &>/dev/null; then
          echo "warning: nix-env was not found in PATH, add nix to userPackages" >&2
          PATH=${self.nix}/bin:$PATH
      fi
      exec nix-env -f '<nixpkgs>' -r -iA userPackages "$@"
    '';

    cssh = super.writeScriptBin "cssh" ''
      #!${super.stdenv.shell}
      exec ${self.tmux-cssh}/bin/tmux-cssh $@
    '';

  };
}