dotfiles/.config/nixpkgs/neovim/plugins/default.nix

{ fetchFromGitHub, fetchpatch, buildNeovimPlugin }:
let
  plugins = builtins.fromJSON (builtins.readFile ./sources.json);

  overrides = {
    "nvim-telescope/telescope-fzf-native.nvim" = {
      dontBuild = false;
    };

    "jose-elias-alvarez/typescript.nvim" = {
      patches = [ ./typescript-nvim-tsserver.patch ];
    };

    "nvim-treesitter/nvim-treesitter" = {
      # these extra rules causes nvim to crash when looking at a deeply nested
      # JSX expression
      patches = [ ./treesitter-jsx.patch ];
    };
  };

  buildPlugin = name: spec:
    let
      nameParts = builtins.split "/" name;
      owner = builtins.head nameParts;
      repo = builtins.elemAt nameParts 2;
    in
    buildNeovimPlugin ({
      name = repo;

      src = fetchFromGitHub {
        inherit owner repo;
        inherit (spec) rev sha256;
      };

      passthru = {
        optional = spec.optional or false;
      };

      dontBuild = true;
    } // (overrides.${name} or {}));
in
builtins.mapAttrs buildPlugin plugins