dotfiles/.config/nixpkgs/zsh/flake.nix

{
  description = "Zsh configuration";

  outputs = { self, nixpkgs }:
    {
      packages.x86_64-linux.default =
        with import nixpkgs {
          system = "x86_64-linux";
        };
        let
          config = symlinkJoin {
            name = "zsh-config";

            paths = [ nix-zsh-completions ];

            nativeBuildInputs = [ makeWrapper ];

            postBuild = ''
              # # broken with newer nix
              # rm $out/share/zsh/site-functions/_nix

              cat <<EOF > $out/share/zsh/.zprofile
              emulate sh -c 'source /etc/profile'
              EOF

              cat <<EOF > $out/share/zsh/.zshenv
              unsetopt GLOBAL_RCS
              EOF

              cat <<EOF > $out/share/zsh/.zshrc
              source $out/share/zsh/plugins/nix/nix-zsh-completions.plugin.zsh
              fpath+=($out/share/zsh/site-functions)

              autoload -U compinit && compinit

              source ${zsh-bd}/share/zsh-bd/bd.plugin.zsh
              source ${zsh-powerlevel10k}/share/zsh-powerlevel10k/powerlevel10k.zsh-theme

              path+=(${lib.makeBinPath [ any-nix-shell ]})

              source ${./config/fzf/fzf.zsh}
              source ${./config/config.zsh}
              source ${./config/p10k.zsh}
              source ${./config/title.zsh}

              if [ -f "\$HOME/.zsh/local.zsh" ]; then
                source "\$HOME/.zsh/local.zsh"
              fi

              # must be last
              source ${zsh-syntax-highlighting}/share/zsh-syntax-highlighting/zsh-syntax-highlighting.zsh
              EOF
            '';
          };
        in
        writeScriptBin "zsh" ''
          #!/bin/sh
          export ZDOTDIR=${config}/share/zsh
          for zsh in $(which -a zsh); do
            if [ "$0" = "$zsh" ]; then
              continue
            fi
            exec "$zsh" "$@"
          done
          echo "Could not find system zsh"
          exit 1
        '';
    };
}