bootstrap/sysa.nix

let
  system = "x86_64-linux";
  inherit (import ./stage0-posix.nix) kaem buildtools0 mescc-tools-extra;

  live-bootstrap-src = builtins.fetchGit {
    url = "https://github.com/fosslinux/live-bootstrap.git";
    rev = "b2e8e0fea0d1715a0c3a2e3cccd64b617c040851";
  };

  mes-src = builtins.fetchurl {
    url = "https://github.com/oriansj/mes-m2/archive/dad1744fa80f52b3b428803c06b09d39c285f500.tar.gz";
    sha256 = "a8da14d1cd6aaa1ff607a571a8ca5948258195c712de05b0f8ad11c215b6b094";
  };

  nyacc-src = builtins.fetchurl {
    url = "https://download.savannah.gnu.org/releases/nyacc/nyacc-1.00.2.tar.gz";
    sha256 = "f36e4fb7dd524dc3f4b354d3d5313f69e7ce5a6ae93711e8cf6d51eaa8d2b318";
  };

  mes = derivation {
    inherit system;
    name = "mes";

    src = live-bootstrap-src;

    mes_src = mes-src;
    nyacc_src = nyacc-src;
    empty = builtins.toFile "empty" "";
    checksums = ./checksums;

    builder = kaem;

    ARCH = "x86";
    PATH = "${buildtools0}/bin:${mescc-tools-extra}/bin";

    args = ["--file" ./mes.kaem];
  };

  tcc-0_9_26-patched-src = builtins.fetchurl {
    url = "https://lilypond.org/janneke/tcc/tcc-0.9.26-1136-g5bba73cc.tar.gz";
  };

  mes-0_23-src = builtins.fetchurl {
    url = "https://mirrors.kernel.org/gnu/mes/mes-0.23.tar.gz";
  };

  tcc-0_9_26 = derivation {
    inherit system;
    name = "tcc-0.9.26";

    src = live-bootstrap-src;

    inherit mes;
    mes_src = mes-0_23-src;
    tcc_src = tcc-0_9_26-patched-src;

    checksums = ./checksums;

    builder = kaem;

    ARCH = "x86";
    PATH = "${buildtools0}/bin:${mescc-tools-extra}/bin:${mes}/bin";

    args = ["--file" ./tcc-0.9.26-patched.kaem];
  };

in
{
  inherit mes tcc-0_9_26;
}